【Shader练习-卡通火焰】

卡通风格的火焰。

全屏显示

R:外焰

G:内焰

B:透贴

R:噪波1

G:噪波2

Shader "ShaderEffect/Shader/Fire" {
    Properties {
        _Mask ("R:外焰 G:内焰 B:透贴",2d) = "blue"{}
        _Noise ("R:噪波1 G:噪波2",2d) = "gray"{}
        _Noise1Params("噪波1 X:大小 Y:流速 Z:强度",vector) = (1.0,0.2,0.2,1.0)
        _Noise2Params("噪波2 X:大小 Y:流速 Z:强度",vector) = (1.0,0.2,0.2,1.0)
        [HDR] _OutCol("外焰颜色",color) = (1.0,1.0,1.0,1.0)
        [HDR] _InnerCol("内焰颜色",color) = (1.0,1.0,1.0,1.0)
    }
    SubShader {
        Tags {
            "Queue" = "Transparent"                     // 调整渲染排序
            "RenderType" = "Transparent"          // 修改为透明模式
            "ForceNoShadowCasting" = "True"             // 不捕获阴影
            "IgnoreProjector"= "True"                   // 不响应投射器
        }
        Pass {
            Name "FORWARD"
            Tags {
                "LightMode"="ForwardBase"
            }
            Blend SrcAlpha OneMinusSrcAlpha  //  修改混合方式 One OneMinusSrcAlpha  或者 SrcAlpha OneMinusSrcAlpha
            
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #pragma multi_compile_fwdbase_fullshadows
            #pragma target 3.0

            uniform sampler2D _Mask;
            uniform sampler2D _Noise;uniform float4 _Noise_ST;
            uniform half3 _Noise1Params;
            uniform half3 _Noise2Params;
            uniform half3 _OutCol;
            uniform half3 _InnerCol;

            struct VertexInput {
                float4 vertex : POSITION;
                float2 uv :TEXCOORD0;// UV信息，采样贴图用
            };
            struct VertexOutput {
                float4 pos : SV_POSITION;
                float2 uv0 : TEXCOORD0;// UV信息 采样Mask
                float2 uv1 : TEXCOORD1;// UV信息 采样_Noise1
                float2 uv2 : TEXCOORD2;// UV信息 采样_Noise2
            };
            VertexOutput vert (VertexInput v) {
                VertexOutput o = (VertexOutput)0;
                o.pos = UnityObjectToClipPos( v.vertex );
                o.uv0 = v.uv;
                // UV向上进行随时间流动
                o.uv1 = v.uv * _Noise1Params.x - float2(0.0,frac(_Time.y * _Noise1Params.y));
                o.uv2 = v.uv * _Noise2Params.x - float2(0.0,frac(_Time.y * _Noise2Params.y));
                return o;
            }
            float4 frag(VertexOutput i) : COLOR
            {
                half wrapMask = tex2D(_Mask,i.uv0).b;// 扰动遮罩,下方比较弱，上方比较强
                half var_Noise1 = tex2D(_Noise,i.uv1).r;//扰动A噪音
                half var_Noise2 = tex2D(_Noise,i.uv2).g;//扰动B噪音
                // 扰动噪音 X 扰动强度 X 扰动遮罩
                half noise = var_Noise1 * _Noise1Params.z * wrapMask + var_Noise2 * _Noise2Params.z * wrapMask;
                float2 wrapUV = i.uv0 - float2(0,noise);

                float3 var_Mask = tex2D(_Mask,wrapUV);

                // 替换颜色
                // 红通道的值换成外焰颜色
                // 绿通道的值换成内焰颜色
                // 透明通道的Alpha 为 内焰+外焰的值
                half3 finalRGB = _OutCol * var_Mask.r + _InnerCol * var_Mask.g;
                half alpha = var_Mask.r + var_Mask.g;
                return half4(finalRGB.r,finalRGB.g,finalRGB.b,alpha);
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

度盘：https://pan.baidu.com/s/1AMAyMDaoYnLmIXuwNRHMJg?pwd=66a1 (opens new window)